MikroTik OmniTik 5 POE AC

The Omnitik 5ac is an outdoor switch/router with a built-in 5Ghz 802.11ac access point, omnidirectional antenna, and 5 gigabit ethernet ports. Be sure to get the POE version. Here are the config instructions

The OmniTik serves as a central rooftop hub with several purposes:

• As a switch to connect multiple apartments or other rooftop devices (LiteBeam, SXTs etc.)
  
• Can output POE power to power LiteBeams or other antennas.
• It acts as an WiFi Access Point for the rooftop, and runs our config of WDS and OSPF so it will mesh with other OmniTiks or SXTsqs within a few blocks
  
• Provides remote management, a console interface and allows speed/traceroute/ping testing of the hub.

Please be sure to see MikroTik Specifics for extra info about Mikrotik devices, how to connect, etc.

The PoE version accepts 12-57V passive PoE on port 1 and can be configured to provide PoE out to ports 2-5.

The small round plastic tabs, shown in the picture above, should be removed for those cable ports you will use - push them firmly inwards to remove. Leave the tabs in unused ports to prevent water entry.

Device specs are available at Mikrotik.com

Uses

• Hub node routing or AP ( for standard 802.11ac hubs )
• Rooftop installations for multi-tenant houses
• Providing public access via the omnidirectional antenna

How to reset

1. Press reset
2. Apply power
3. Watch the power led, once it blinks, STOP pressing the reset button
4. It will beep one time
5. Once you hear two beeps, you should be able to access it.

How to upgrade the firmware

1. Upload the routeros-mipsbe-x.x.x.npk file in http://192.168.88.1/webfig/#Files
2. Select System Reboot

How to downgrade firmware

1. Upload the routeros-mipsbe-x.x.x.npk file in http://192.168.88.1/webfig/#Files
2. Go to Terminal and type /system package downgrade;

ConfigurationsConfiguration Instructions:

Standard Omnitik mesh config:

1. Download Stable Firmware and Generate Configuration

Don't use version 7 of firmware. It won't work with the configgen file! Make sure your firmware is v6.x.x.

You will need your Network Number or NN. You can find out your NN using your Install Number (request number) received by email when you registered. To find out what is your NN please see Network Number.

1. Download the latest stable v6 firmware - see Mikrotik Firmware.
2. Generate a configuration file for your Network Number by going to the NYC Mesh configuration generator. Configgen. Type in the network number and click “Download Config”. For SXTsq config file see below

2. Connect to the Router

1. To connect to the Omnitik wirelessly, find the router’s SSID and connect to it. (For SXTsq connect via cable)
2. To connect with a cable, plug one end of a patch cable into the Omnitik’s Port 2 and the other end into your computer’s LAN port. Set your computer to DHCP (automatic) and it will get an address like 192.168.88.xxx.
3. Navigate to the default Mikrotik IP 192.168.88.1 in your web browser. This will open the Mikrotik GUI. The default username is admin and there is no password.

3. Upload Firmware

1. Open the Mikrotik GUI in your browser.
2. Click “Webfig” in the top right corner.
3. Click “Files” in the left side menu.
4. Click “Choose File” at the top.
5. Navigate to where you saved the firmware, select the file and click “Open”. You will see the file appear in the interface.
6. Wait for the firmware to fully upload (you will see the upload progress in the bottom left corner). This firmware will automatically be installed when you reboot with the new configuration (see next section).

4. Upload Configuration

1. If you are using a Mac or Linux operating system, go into Terminal, navigate to the folder where you’ve saved the config and enter the following command:

scp -o StrictHostKeyChecking=no rooftop-ospf.rsc admin@192.168.88.1:flash/

2. If you are using a Windows operating system, go into Command Prompt, navigate to the folder where you’ve saved the config and enter the following command. You must download pscp.exe from PuTTY (64-bit or 32-bit) to the same folder then run:

pscp -scp rooftop-ospf.rsc admin@192.168.88.1:flash/

3. If asked “Dangerous Reset anyway?” type in Y and return/enter.
4. Reopen the Mikrotik GUI in your web browser and navigate back to “Files” as described in section 3 above. You should see the config file you just uploaded.
5. Click “System” in the left side menu.
6. Click “Reset Configuration” in the left side menu dropdown. Select:

• No Default Configuration
• Run After Reset: flash/rooftop-ospf.rsc (click the popup on the right to select this)

7. Click "Reset Configuration"
8. The Omnitik will now reboot (and install new firmware if you uploaded it). If it plays some beeps, ending with a short tune Kernkraft 400, the configuration was a success!

The Omnitik IP address has changed to a 10.69.x.x address. This is generated from the network number, e.g. for network number 1234 the IP address will be 10.69.12.34

5. Change the Password

1. Click “System” in the left side menu.
2. Click “Password” in the left side menu dropdown.
3. Type in the standard NYC Mesh password.

6. Force on POE for a LiteBeam

A typical install also has a LiteBeam on port 5 that is powered from the OmniTik. To do this you must-

1. Go to Webfig>interfaces>ether5
2. Change "POE Out" to "forced on"

Other devices can be powered from other ports if you change this setting

Omnitik config

Here are the current config instructions. As discussed in the MikroTik Specifics page, these devices need a script to be generated and loaded onto the device rather than a saved config file.
We now have a script generator you can find here https://configgen.nycmesh.net/
Here is a slideshow of configuring an OmniTik

Wireless interface explanation

• wlan1
  • SSID example: nycmesh-136-omni
  • AP bridge (MikroTik term)
    
  • manually connected to by other Omni's to avoid avoid route flapping behavior exhibited by the automatic mesh (wlan3)
• wlan2
  • SSID example: -NYC Mesh Community WiFi-  
  • Also ap bridge
  • only difference to wlan1 is bridge filter and and ip firewall rule
• wlan3
  • SSID example: nycmesh-wds
  • wds slave slave 
  • all automatic mesh connections communicate through this interface
  • wds bridge
    • is not running a dhcp server
    • OSPF will route to other connections first since bridge for this interface is higher at 100
• wlan4
  • station bridge for connecting to an access point ex.  wlan1

:global nodenumber 1111
:global bgpasn 61111
:global ipprefix "10.70.111"
:global iptenantsrange 10.70.111.5-10.70.111.119
:global iptenantsgw 10.70.111.1
:global ippublicrange 10.70.111.130-10.70.111.180
:global ippublicgw 10.70.111.129
:global dns 10.10.10.10,1.1.1.1

/delay 15

:for j from=1 to=4 step=1 do={
  :for i from=2000 to=50 step=-400 do={
    :beep frequency=$i length=11ms;
    :delay 11ms;
  }
  :for i from=800 to=2000 step=400 do={
    :beep frequency=$i length=11ms;
    :delay 11ms;
  }
}

:foreach x in=[/interface wireless find] do={ /interface wireless reset-configuration $x }

:for t from=1200 to=350 step=-50 do={
  :beep frequency=$t length=33ms;
  :delay 33ms;
}

:beep frequency=500 length=100ms

/ip address add address=192.168.88.1/24 interface=ether3 network=192.168.88.0

:beep frequency=600 length=100ms

/interface ethernet
set [ find default-name=ether5 ] poe-out=forced-on

:beep frequency=700 length=100ms

/interface wireless security-profiles
add authentication-types=wpa-psk,wpa2-psk management-protection=allowed mode=\
    dynamic-keys name=nycmeshnet supplicant-identity=nycmesh \
    wpa-pre-shared-key=nycmeshnet wpa2-pre-shared-key=nycmeshnet

:beep frequency=800 length=100ms

/interface wireless
set [ find default-name=wlan1 ] band=5ghz-a/n/ac channel-width=20/40/80mhz-Ceee disabled=no distance=indoors frequency=auto mode=ap-bridge security-profile=nycmeshnet ssid=("nycmesh-" . $nodenumber . "-omni")  wireless-protocol=802.11 wps-mode=disabled
add disabled=no master-interface=wlan1 name=wlan2 ssid="-NYC Mesh Community WiFi-" wps-mode=disabled

:beep frequency=900 length=100ms

/interface bridge
add auto-mac=yes name=publicaccess
add auto-mac=yes name=tenants

:beep frequency=1000 length=100ms

/ip address
add address=($ipprefix . ".1/25") interface=tenants network=($ipprefix . ".0")
add address=($ipprefix . ".129/26") interface=publicaccess network=($ipprefix . ".128")

:beep frequency=1100 length=100ms

/interface bridge port
add bridge=tenants interface=ether1
add bridge=tenants interface=ether2
add bridge=tenants interface=ether3
add bridge=tenants interface=ether4
add bridge=tenants interface=wlan1
add bridge=publicaccess interface=wlan2

:beep frequency=1200 length=100ms

/ip pool
add name=tenants ranges=$iptenantsrange
add name=publicaccess ranges=$ippublicrange

:beep frequency=1300 length=100ms

/ip dhcp-server
add address-pool=tenants disabled=no interface=tenants name=tenantsdhcp
add address-pool=publicaccess disabled=no interface=publicaccess name=publicaccessdhcp

:beep frequency=1400 length=100ms

/routing bgp instance
set default as=$bgpasn disabled=no

:beep frequency=1500 length=100ms

/routing bgp network
add network=($ipprefix . ".0/24") synchronize=no

:beep frequency=1600 length=100ms

/ip dhcp-server network
add address=($ipprefix . ".0/25") dns-server=10.10.10.10 gateway=($ipprefix . ".1") netmask=25
add address=($ipprefix . ".128/26") dns-server=10.10.10.10 gateway=($ipprefix . ".129") netmask=25

:beep frequency=1700 length=100ms

/ip firewall filter
add action=accept chain=input protocol=icmp
add action=drop chain=forward in-interface=publicaccess out-interface=tenants
add action=drop chain=input in-interface=publicaccess
add action=accept chain=forward
add action=accept chain=input

:beep frequency=1800 length=100ms

/system clock set time-zone-name=America/New_York
/system identity set name=("nycmesh-" . $nodenumber . "-omni")

:beep frequency=500 length=200ms;
:delay 500ms;
:beep frequency=500 length=200ms;
:delay 200ms;
:beep frequency=800 length=500ms;
:delay 50ms;